SHARP-PC1401


Hier ist jetzt ein etwas komplizierteres Programm. Dies ist ein Rechentrainer. Wenn du nur sehen möchtest, wie das Programm abläuft, kannst Du das YouTube-Filmchen ansehen.

Der vollständige Rechentrainer ist hier gelistet:

10: CLEAR : RANDOM : WAIT

20: PRINT "RECHENTRAINER"

30: FOR F = 0 TO 8

40: BEEP 1

49: REM ZEILE 50 SPRINGT 120, 240, 360, 480 AN:

50: GOTO RND 4*120

119: REM ADDIEREN:

120: WAIT 80

130: A = RND 9 : B = INT(RND(9-A))

140: PRINT A;"+";B;"="

150: C = A + B

160: GOTO 600

239: REM SUBTRAHIEREN:

240: WAIT 80

250: A = RND 50+10 : B = A - RND 9

260: PRINT A;"-";B;"="

270: C = A - B

280: GOTO 600

359: REM MULTIPLIZIEREN:

360: WAIT 80

370: A = RND 8

380: B = RND (10/A)

390: C = A*B : IF C > 9 THEN 370

400: PRINT A;"*";B;"="

410: GOTO 600

479: REM DIVIDIEREN:

480: WAIT 80

490: B = RND 10

500: A = B* (RND 8+1)

510: PRINT A;"/";B;"="

520: C = A / B

600: Z = 0

610: L$ = INKEY$: Z=Z+1 : IF L$="" THEN 610

612: WAIT 40

614: PRINT L$

620: K = VAL L$

630: WAIT 80

635: IF K = C LET Y = 3 + INT(30/Z) : PRINT "GUT:" : GOTO 660

640: Y = 0: BEEP 1 : PRINT "NEIN, ";C

660: PRINT "PUNKTE: "; Y

670: NEXT F